FileMgr

✏️ /usr/share/aclocal-1.16/ar-lib.m4

✕ Tutup

##                                                          -*- Autoconf -*-
# Copyright (C) 2011-2020 Free Software Foundation, Inc.
#
# This file is free software; the Free Software Foundation
# gives unlimited permission to copy and/or distribute it,
# with or without modifications, as long as this notice is preserved.

# AM_PROG_AR([ACT-IF-FAIL])
# -------------------------
# Try to determine the archiver interface, and trigger the ar-lib wrapper
# if it is needed.  If the detection of archiver interface fails, run
# ACT-IF-FAIL (default is to abort configure with a proper error message).
AC_DEFUN([AM_PROG_AR],
[AC_BEFORE([$0], [LT_INIT])dnl
AC_BEFORE([$0], [AC_PROG_LIBTOOL])dnl
AC_REQUIRE([AM_AUX_DIR_EXPAND])dnl
AC_REQUIRE_AUX_FILE([ar-lib])dnl
AC_CHECK_TOOLS([AR], [ar lib "link -lib"], [false])
: ${AR=ar}

AC_CACHE_CHECK([the archiver ($AR) interface], [am_cv_ar_interface],
  [AC_LANG_PUSH([C])
   am_cv_ar_interface=ar
   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int some_variable = 0;]])],
     [am_ar_try='$AR cru libconftest.a conftest.$ac_objext >&AS_MESSAGE_LOG_FD'
      AC_TRY_EVAL([am_ar_try])
      if test "$ac_status" -eq 0; then
        am_cv_ar_interface=ar
      else
        am_ar_try='$AR -NOLOGO -OUT:conftest.lib conftest.$ac_objext >&AS_MESSAGE_LOG_FD'
        AC_TRY_EVAL([am_ar_try])
        if test "$ac_status" -eq 0; then
          am_cv_ar_interface=lib
        else
          am_cv_ar_interface=unknown
        fi
      fi
      rm -f conftest.lib libconftest.a
     ])
   AC_LANG_POP([C])])

case $am_cv_ar_interface in
ar)
  ;;
lib)
  # Microsoft lib, so override with the ar-lib wrapper script.
  # FIXME: It is wrong to rewrite AR.
  # But if we don't then we get into trouble of one sort or another.
  # A longer-term fix would be to have automake use am__AR in this case,
  # and then we could set am__AR="$am_aux_dir/ar-lib \$(AR)" or something
  # similar.
  AR="$am_aux_dir/ar-lib $AR"
  ;;
unknown)
  m4_default([$1],
             [AC_MSG_ERROR([could not determine $AR interface])])
  ;;
esac
AC_SUBST([AR])dnl
])

Batal

⬅ share 33 item

Nama	Tipe	Ukuran	Diubah	Perm	Aksi
📁 internal	dir	—	14/09/24 23:09	0755	📂
📄 amversion.m4	m4	1.6 KB	17/03/20 09:08	0644	✏️ ⬇
📄 ar-lib.m4	m4	2 KB	02/01/20 02:43	0644	✏️ ⬇
📄 as.m4	m4	767 B	02/01/20 02:43	0644	✏️ ⬇
📄 auxdir.m4	m4	2.4 KB	02/01/20 02:43	0644	✏️ ⬇
📄 cond-if.m4	m4	1 KB	02/01/20 02:43	0644	✏️ ⬇
📄 cond.m4	m4	1 KB	02/01/20 02:43	0644	✏️ ⬇
📄 depend.m4	m4	7.1 KB	02/01/20 02:43	0644	✏️ ⬇
📄 depout.m4	m4	2.7 KB	26/02/20 11:25	0644	✏️ ⬇
📄 dmalloc.m4	m4	906 B	02/01/20 02:43	0644	✏️ ⬇
📄 extra-recurs.m4	m4	738 B	02/01/20 02:43	0644	✏️ ⬇
📄 gcj.m4	m4	649 B	02/01/20 02:43	0644	✏️ ⬇
📄 init.m4	m4	7.8 KB	02/01/20 02:43	0644	✏️ ⬇
📄 install-sh.m4	m4	681 B	02/01/20 02:43	0644	✏️ ⬇
📄 lead-dot.m4	m4	641 B	02/01/20 02:43	0644	✏️ ⬇
📄 lex.m4	m4	689 B	02/01/20 02:43	0644	✏️ ⬇
📄 lispdir.m4	m4	2.1 KB	02/01/20 02:43	0644	✏️ ⬇
📄 maintainer.m4	m4	1.6 KB	02/01/20 02:43	0644	✏️ ⬇
📄 make.m4	m4	1.4 KB	02/01/20 02:43	0644	✏️ ⬇
📄 missing.m4	m4	1.1 KB	02/01/20 02:43	0644	✏️ ⬇
📄 mkdirp.m4	m4	1.3 KB	02/01/20 02:43	0644	✏️ ⬇
📄 obsolete.m4	m4	1008 B	02/01/20 02:43	0644	✏️ ⬇
📄 options.m4	m4	1.1 KB	02/01/20 02:43	0644	✏️ ⬇
📄 prog-cc-c-o.m4	m4	1.7 KB	02/01/20 02:43	0644	✏️ ⬇
📄 python.m4	m4	9.2 KB	27/09/23 19:16	0644	✏️ ⬇
📄 runlog.m4	m4	718 B	02/01/20 02:43	0644	✏️ ⬇
📄 sanity.m4	m4	2.6 KB	02/01/20 02:43	0644	✏️ ⬇
📄 silent.m4	m4	1.9 KB	02/01/20 02:43	0644	✏️ ⬇
📄 strip.m4	m4	1.4 KB	02/01/20 02:43	0644	✏️ ⬇
📄 substnot.m4	m4	675 B	02/01/20 02:43	0644	✏️ ⬇
📄 tar.m4	m4	4.4 KB	02/01/20 02:43	0644	✏️ ⬇
📄 upc.m4	m4	836 B	02/01/20 02:43	0644	✏️ ⬇
📄 vala.m4	m4	1.6 KB	02/01/20 02:43	0644	✏️ ⬇

✏️ Rename

🔑 Ubah Permission